Lekce 1 - Výjimky

V této sekci se budeme věnovat práci se soubory. Než však můžeme začít zapisovat a číst, měli bychom vyřešit, jak ošetřit chybové stavy programu, kterých při práci se soubory bude nastávat mnoho.

V našem programu může často dojít k chybě. Tím nemyslím chybě z důvodu, že byl program funkčně špatně napsaný, takových chyb se jsme schopni dobře vyvarovat. Obecně se jedná zejména o chyby, které zapříčinily tzv. vstupně/výstupní operace. V anglické literatuře se hovoří o input/output nebo zkráceně o IO. Jedná se např. o vstup uživatele z konzole, ze souboru, výstup do souboru, na tiskárnu a podobně. V zásadě platí, že zde figuruje uživatel, který nám může zadat nesmyslný vstup, neexistující nebo nevalidní soubor, odpojit tiskárnu a podobně. My však nenecháme program spadnout s chybou, naopak budeme zranitelná místa v programu ošetřovat a na danou skutečnost uživatele upozorníme.

Aktivní ošetření chyb

První možnost ošetření chyb nazýváme jako aktivní. V programu nalezneme všechna zranitelná místa a ošetříme je podmínkami. Jako učebnicový příklad se zpravidla používá dělení nulou. Představme si program, který používá třídu Matematika, která má metodu Podil. Třída by mohla vypadat např. takto:

Class Matematika
    Public Shared Function Podil(a As Integer, b As Integer)
        Return a / b
    End Function
    ...
End Class

Nyní třídu použijeme takovýmto způsobem:

Console.WriteLine("Zadejte dělitele a dělence k výpočtu podílu:")
Dim a As Integer = Console.ReadLine()
Dim b As Integer = Console.ReadLine()
Console.WriteLine(Matematika.Podil(a, b))

Pokud nyní programu uživatel zadá čísla 12 a 0, program spadne s chybou, protože nulou nelze dělit. Aktivně chybu ošetříme jednoduchou podmínkou v programu:

Console.WriteLine("Zadejte dělitele a dělence k výpočtu podílu:")
Dim a As Integer = Console.ReadLine()
Dim b As Integer = Console.ReadLine()
If b <> 0 Then
    Console.WriteLine(Matematika.Podil(a, b))
Else
    Console.WriteLine("Nulou nelze dělit.")
End If

Nyní si musíme při každém použití metody tedy hlídat, jestli do druhého parametru nevkládáme nulu. Představte si, že by metoda brala parametrů 10 a používali jsme ji v programu několikrát. Určitě je velmi složité takto ošetřovat všechny vstupy ve všech případech.

Řešením by mohlo být vložit kontrolu přímo do metody. Máme tu však nový problém: Jakou hodnotu vrátíme, když bude 2. parametr nulový? Potřebujeme hodnotu, ze které poznáme, že výpočet neproběhl korektně. To je však problém, když zvolíme např. nulu, nepoznáme, zda 0/12 je chybný výpočet či nikoli. Nevíme, zda 0 značí výsledek nebo chybu. Ani zápornými čísly si nepomůžeme. V .NETu je podobná metoda TryParse, která vrací Boolean a hodnota se předává přes modifikovaný parametr. To je však nepřehledné. Parsování hodnot je 2. klasický příklad zranitelného vstupu od uživatele. Další jsou souborové operace, kde soubor nemusí existovat, nemusíme na něj mít práva, může s ním být zrovna pracováno a podobně.

Pasivní ošetření chyb

Když je operace složitější a bylo by příliš náročné ošetřovat všechny možné chybové stavy, nastupují výjimky, tzv. pasivní ošetření chyb. Nás totiž vůbec nemusí zajímat vnitřní logika v metodě, kterou voláme. Pokusíme se nebezpečnou část kódu spustit v "chráněném režimu". Tento režim je nepatrně pomalejší a liší se tím, že pokud dojde k chybě, máme možnost ji odchytit a zabránit pádu programu. O chybě zde hovoříme jako o výjimce. Využíváme k tomu tzv. try-catch bloky:

Try

Catch ex As Exception

End Try

Do bloku try umístíme nebezpečnou část kódu. Pokud nastane v bloku try chyba, jeho vykonávání se přeruší a program přejde do bloku catch. Pokud vše proběhne v pořádku, try se vykoná celý a catch se přeskočí. Vyzkoušejme si situaci na našem předchozím příkladu:

Try
    Console.WriteLine(Matematika.Podil(a, b))
Catch ex As Exception
    Console.WriteLine("Při dělení nastala chyba.")
End Try

Kód je jednodušší v tom, že nemusíme ošetřovat všechna zranitelná místa a přemýšlet, co vše by se mohlo pokazit. Nebezpečný kód pouze obalíme blokem Try a všechny chyby se zachytí v Catch. Samozřejmě do try-catch bloku umístíme jen to nezbytně nutné, ne celý program

Nyní tedy již víme, jak ošetřit situace, kdy uživatel zadává nějaký vstup, který by mohl vyvolat chybu. Nemusí se jednat jen o souborové operace, výjimky mají velmi širokou oblast použití. Ostatně např. metoda Integer.TryParse, kterou dobře známe a kterou jsme k ošetření vstupů používali, v sobě interně blok try-catch obsahuje. Dokážeme náš program napsat tak, aby se nedal jednoduše uživatelem shodit.

Použití výjimek při práci se soubory

Jak již bylo řečeno, souborové operace mohou vyvolat mnoho výjimek, proto se soubory vždy pracujeme v try-catch bloku. Existuje také několik dalších konstrukcí, které při výjimkách můžeme využívat.

Finally

Do try-catch bloku můžeme přidat ještě 3. blok a to Finally. Ten se spustí vždy ať k výjimce došlo či nikoli. Představte si následující metodu pro uložení nastavení. Metody pro obsluhu souboru budou smyšlené:

Public Sub UlozNastaveni()
    Try
        OtevriSoubor("soubor.dat")
        ZapisDoSouboru(nastaveni)
    Catch
        Console.WriteLine("Chyba při zápisu do souboru.")
    End Try
    If SouborJeOtevreny() Then
        ZavriSoubor()
    End If
End Sub

Metoda se soubor pokusí otevřít a zapsat do něj objekt nastavení. Při chybě vypíše hlášku do konzole. Otevřený soubor musíme opět uzavřít. Vypisovat chyby přímo v metodě je však ošklivé, to ostatně již víme, metody a objekty obecně by měly provádět jen logiku a komunikaci s uživatelem obstarává ten, kdo je volá. Dejme tedy metodě návratovou hodnotu Boolean a vracejme true/false podle toho, zda se operace povedla či nikoli:

Public Function UlozNastaveni() As Boolean
    Try
        OtevriSoubor()
        ZapisDoSouboru()
        Return True
    Catch
        Return False
    End Try
    If SouborJeOtevreny() Then
        ZavriSoubor()
    End If
End Function

Na první pohled to vypadá, že se soubor vždy uzavře. Celý kód je však v nějaké metodě, ve které voláme return. Jak víme, return ukončí metodu a nic za ním se již neprovede.

Soubor by zde vždy zůstal otevřený a uzavření by se již neprovedlo. Jako následek by to mohlo mít, že by byl poté soubor nepřístupný. Pokud vložíme zavření souboru do bloku Finally, vykoná se vždy. VB.NET si pamatuje, že blok try-catch obsahoval Finally a po opuštění sekce Catch zavolá Finally:

Public Function UlozNastaveni() As Boolean
    Try
        OtevriSoubor()
        ZapisDoSouboru()
        Return True
    Catch
        Return False
    Finally
        If SouborJeOtevreny() Then
            ZavriSoubor()
        End If
    End Try
End Function

Finally se tedy používá u výjimek na úklidové práce, dochází zde k zavírání souborů, uvolňování paměti a podobně.

Celou situaci jsem nyní značně zjednodušil. Pro každý typ souborů poskytuje VB.NET třídu zapisovače a čteče (writer a reader). Metoda pro uložení např. nastavení by ve VB.NET reálně vypadala asi takto:

Public Function UlozNastaveni() As Boolean
    Dim z As ZapisovacSouboru = Nothing
    Try
        z = New ZapisovacSouboru("soubor.dat")
        z.Zapis(objekt)
        Return True
    Catch
        Return False
    Finally
        If z IsNot Nothing Then
            z.Zavri()
        End If
    End Try
End Function

Takto se opravdu reálně se soubory pracuje, pouze třídu jsem si vymyslel. Do instance zapisovače umístíme nejprve Nothing. Poté, již v bloku Try, zkusíme vytvořit zapisovač na souboru soubor.dat a zapsat nějaký objekt. Pokud se vše povede, vrátíme True (samozřejmě se poté ještě zavolá blok Finally). Operace může selhat ze dvou důvodů. Buď se do souboru nepovede zapsat nebo se nám soubor pro zápis ani nepovede otevřít. Výjimku v každém případě zachytíme a vrátíme False, z čeho se poté pozná, že se metodě uložení nepodařilo. Blok Finally zavře soubor, který zapisovač otevřel. Jelikož se ale otevření nemuselo povést, musíme se nejprve podívat, zda se zapisovač vůbec vytvořil, abychom měli co zavírat. Metodu bychom volali např. takto:

If Not UlozNastaveni() Then
    Console.WriteLine("Nepodařilo se uložit nastavení.")
End If

Blok Catch můžeme vynechat a nechat metodu, aby výjimku klidně vyvolala. Budeme počítat s tím, že se s výjimkou vypořádá ten, kdo metodu zavolal, nikoli metoda sama. Je to tak lepší, ušetříme návratovou hodnotu metody (kterou lze poté použít pro něco jiného) a kód se nám zjednoduší:

Public Sub UlozNastaveni()
    Dim z As ZapisovacSouboru = Nothing
    Try
        z = New ZapisovacSouboru("soubor.dat")
        z.Zapis(objekt)
    Finally
        If z IsNot Nothing Then
            z.Zavri()
        End If
    End Try
End Sub

Metodu bychom nyní volali takto:

Try
    UlozNastaveni()
Catch
    Console.WriteLine("Nepodařilo se uložit nastavení.")
End Try

Nyní si ukážeme, jak celou situaci ještě více zjednodušit. Použijeme konstrukci Using.

Using

Visual Basic .NET umožňuje značně zjednodušit práci s instancemi tříd ke čtení a zápisu do souborů. Výše uvedený blok můžeme zapsat pomocí notace Using, která nahrazuje bloky Try a Finally. Obrovskou výhodou je, že blok Finally VB.NET vygeneruje sám a sám zajistí, aby daná instance readeru nebo writeru soubor uzavřela. Metoda UlozNastaveni() by tedy vypadala s pomocí Using takto:

Public Sub UlozNastaveni()
    Using z As New ZapisovacSouboru("soubor.dat")
        z.Zapis(objekt)
    End Using
End Sub

Vidíme, že se kód extrémně zjednodušil, i když dělá v podstatě to samé. Při volání metody opět použijeme try-catch blok. Nezapomeňte, že Using nahrazuje pouze try-finally, nikoli Catch!. Metodu, ve které se použivá Using, musíme stejně volat v try-catch bloku.

Nyní jsme dospěli přesně tam, kam jsem chtěl. K veškerým manipulacím se soubory totiž budeme v následujících tutoriálech používat konstrukci Using. Kód bude jednodušší a nikdy se nám nestane, že bychom soubor zapomněli zavřít.

K výjimkám se ještě jednou vrátíme, ukážeme si, jak odchytávat jen některé typy výjimek, které hotové třídy výjimek můžeme v našich programech používat a také, jak vytvořit výjimku vlastní. Teď jsem však chtěl vysvětlit jen potřebné minimum pro práci se soubory a ne vám zbytečně plést hlavu složitými konstrukcemi

Příště, Úvod do práce se soubory, se podíváme, jak to funguje s právy k zápisu do souborů v systému Windows a vyzkoušíme si několik prvních souborových operací.