8. díl - Aréna s mágem (dědičnost a polymorfismus)

Ostatní jazyky Visual Basic .NET Objektově orientované programování Aréna s mágem (dědičnost a polymorfismus)

V minulém dílu tutoriálů o Visual Basic .NET jsme si vysvětlili dědičnost a polymorfismus. Dnes máme slíbeno, že si je vyzkoušíme v praxi. Bude to opět na naší aréně, kde z bojovníka oddědíme mága. Tento tutoriál již patří k těm náročnějším a bude tomu tak i u dalších. Proto si průběžně procvičujte práci s objekty, zkoušejte si naše cvičení a také vymýšlejte nějaké své aplikace, abyste si zažili základní věci. To, že je tu přítomen celý seriál neznamená, že ho celý najednou přečtete a pochopíte :) Snažte se programovat průběžně.

Mág

Než začneme něco psát, shodněme se na tom, co by měl mág umět. Mág bude fungovat stejně, jako bojovník. Kromě života bude mít však i manu. Zpočátku bude mana plná. V případě plné many může mág vykonat magický útok, který bude mít pravděpodobně vyšší damage, než útok normální (ale samozřejmě záleží na tom, jak si ho nastavíme). Tento útok manu vybije na 0. Každé kolo se bude mana zvyšovat o 10 a mág bude podnikat jen běžný útok. Jakmile se mana zcela doplní, opět bude moci magický útok použít. Mana bude zobrazena grafickým ukazatelem, stejně jako život.

Vytvoříme tedy třídu Mag.vb, zdědíme ji z Bojovnik a dodáme ji atributy, které chceme oproti bojovníkovi navíc. Bude tedy vypadat takto (opět si ji okomentujte):

Class Mag
        Inherits Bojovnik
        Private mana As Integer
        Private maxMana As Integer
        Private magickyUtok As Integer
End Class

V mágovi nemáme zatím přístup ke všem proměnným, protože jsou v bojovníkovi nastavené jako privátní. Musíme třídu Bojovnik lehce upravit. Změníme modifikátory Private u atributů na Protected. Budeme potřebovat jen kostka a jmeno, ale klidně nastavíme jako Protected všechny atributy charakteru, protože se v budoucnu mohou hodit, kdybychom se rozhodli oddědit další typy bojovníků. Naopak atribut zprava není vhodné nastavovat jako Protected, protože nesouvisí s bojovníkem, ale s nějakou vnitřní logikou třídy. Třída tedy bude vypadat nějak takto:

Protected jmeno As String
Protected zivot As Integer
Protected maxZivot As Integer
Protected utok As Integer
Protected obrana As Integer
Protected kostka As Kostka
Private zprava As String

...

Přejděme ke konstruktoru.

Konstruktor potomka

VB.NET nedědí konstruktory! Je to pravděpodobně z toho důvodu, že předpokládá, že potomek bude mít navíc nějaké atributy a původní konstruktor by u něj byl na škodu. To je i náš případ, protože konstruktor mága bude brát oproti tomu z bojovníka navíc 2 parametry (mana a magický útok).

Definujeme si tedy konstruktor v potomkovi, který bere parametry potřebné pro vytvoření bojovníka a několik parametrů navíc pro mága.

O potomků je nutné vždy volat konstruktor předka, je to z toho důvodu, že bez volání konstruktoru nemusí být instance správně inicializovaná. Konstruktor předka nevoláme pouze v případě, že žádný nemá. Náš konstruktor musí mít samozřejmě všechny parametry potřebné pro předka plus ty nové, co má navíc potomek. Některé potom předáme předkovi a některé si zpracujeme sami. Konstruktor předka se vykoná před naším konstruktorem.

V VB.NET existuje klíčové slovo MyBase, které je podobné námi již známému Me. Narozdíl od Me, které odkazuje na konkrétní instanci třídy, MyBase odkazuje na předka. My tedy můžeme zavolat konstruktor předka s danými parametry a poté vykonat navíc inicializaci pro mága.

Konstruktor mága bude tedy vypadat takto:

Public Sub New(jmeno As String, zivot As Integer, utok As Integer, obrana As Integer, kostka As Kostka, mana As Integer, magickyUtok As Integer)
        MyBase.New(jmeno, zivot, utok, obrana, kostka)
        Me.mana = mana
        Me.maxMana = mana
        Me.magickyUtok = magickyUtok
End Sub

Pozn.: Stejně můžeme volat i jiný konstruktor v té samé třídě (ne předka), jen místo MyBase použijeme Me.

Přesuňme se nyní do Module1.vb a druhého bojovníka (Shadow) změňme na mága, např. takto:

Dim gandalf As Bojovnik = New Mag("Gandalf", 60, 15, 12, kostka, 30, 45)

Změnu samozřejmě musíme udělat i v řádku, kde bojovníka do arény vkládáme. Všimněte si, že mága ukládáme do proměnné typu Bojovnik. Nic nám v tom nebrání, protože bojovník je jeho předek. Stejně tak si můžeme typ proměnné změnit na Mag. Když aplikaci nyní spustíme, bude fungovat úplně stejně, jako předtím. Mág vše dědí z bojovníka a zatím tedy funguje jako bojovník.

Polymorfismus a přepisování metod

Bylo by výhodné, kdyby objekt Arena mohl s mágem pracovat stejným způsobem jako s bojovníkem. My již víme, že takovémuto mechanismu říkáme polymorfismus. Aréna zavolá na objektu metodu Utoc() se soupeřem v parametru. Nestará se o to, jestli bude útok vykonávat bojovník nebo mág, bude s nimi pracovat stejně. U mága si tedy přepíšeme metodu Utoc() z předka. Přepíšeme zděděnou metodu tak, aby útok pracoval s manou, hlavička metody však zůstane stejná.

Abychom mohli nějakou metodu přepsat, musí být v předkovi označena jako přepisovatelná (v některých jazycích se takovým metodám říká virtuální). Nehledejte za tím žádnou vědu, jednoduše pomocí klíčového slova Overridable VB.NET sdělíme, že si přejeme, aby potomek mohl tuto metodu přepsat. Hlavičku metody v Bojovnik.vb tedy změníme na:

Public Overridable Sub Utoc(souper As Bojovnik)

Když jsme u metod, budeme ještě jistě používat metodu NastavZpravu(), ta je však privátní. Označme ji jako Protected:

Protected Sub NastavZpravu(zprava As String)

Pozn. Při návrhu bojovníka jsme samozřejmě měli myslet na to, že se z něj bude dědit a již označit vhodné atributy a metody jako Protected, případně metody jako přepisovatelné. Klíčovým slovem Overridable je označena metoda, kterou lze v potomkovi přepsat, jinak to není možné. V tutoriálu k bojovníkovi jsem vás tím však nechtěl zbytečně zatěžovat, proto musíme modifikátory změnit až teď, kdy jim rozumíme :)

Metoda Utoc() v bojovníkovi bude tedy Public Overridable. Nyní se vraťme do potomka a pojďme ji přepsat. Metodu normálně definujeme v Mag.vb tak, jak jsme zvyklí. Za modifikátorem Public však ještě použijeme klíčové slovo Overrides, které značí, že si jsme vědomi toho, že se metoda zdědila, ale přejeme si změnit její chování.

Public Overrides Sub Utoc(souper As Bojovnik)

Podobně jsme přepisovali metodu ToString() u našich objektů, každý objekt v VB.NET je totiž odděděný od System.Object, který obsahuje 4 metody, jedna z nich je i ToString(). Při její implementaci tedy musíme použít Overrides.

Chování metody Utoc() nebude nijak složité. Podle hodnoty many buď provedeme běžný útok nebo útok magický. Hodnotu many potom buď zvýšíme o 10 nebo naopak snížíme na 0 v případě magického útoku.

Public Overrides Sub Utoc(souper As Bojovnik)
        Dim uder As Integer = 0
        ' Mana není naplněna
        If mana < maxMana Then
                mana += 10
                If mana > maxMana Then
                        mana = maxMana
                End If
                uder = utok + kostka.hod()
                NastavZpravu([String].Format("{0} útočí s úderem za {1} hp", jmeno, uder))
        Else
                ' Magický útok
                uder = magickyUtok + kostka.hod()
                NastavZpravu([String].Format("{0} použil magii za {1} hp", jmeno, uder))
                mana = 0
        End If
        souper.BranSe(uder)
End Sub

Kód je asi srozumitelný. Všimněte si omezení many na maxMana, může se nám totiž stát, že tuto hodnotu přesáhneme, když ji zvyšujeme o 10. Když se nad kódem zamyslíme, tak útok výše v podstatě vykonává původní metoda Utoc(). Jistě by bylo přínosné zavolat podobu metody na předkovi místo toho, abychom chování opisovali. K tomu opět použijeme MyBase:

Public Overrides Sub Utoc(souper As Bojovnik)
        ' Mana není naplněna
        If mana < maxMana Then
                mana += 10
                If mana > maxMana Then
                        mana = maxMana
                End If
                MyBase.Utoc(souper)
        Else
                ' Magický útok
                Dim uder As Integer = magickyUtok + kostka.hod()
                NastavZpravu([String].Format("{0} použil magii za {1} hp", jmeno, uder))
                souper.BranSe(uder)
                mana = 0
        End If
End Sub

Opět vidíme, jak můžeme znovupoužívat kód. S dědičností je spojeno opravdu mnoho technik, jak si ušetřit práci. V našem případě to ušetří několik řádků, ale u většího projektu by to mohlo mít obrovský význam.

Aplikace nyní funguje tak, jak má.

Tahová hra aréna s mágem v C#

Aréna nás však neinformuje o maně mága, pojďme to napravit. Přidáme mágovi veřejnou metodu GrafickaMana(), která bude obdobně jako u života vracet String s grafickým ukazatelem many.

Abychom nemuseli logiku se složením ukazatele psát dvakrát, upravíme metodu GrafickyZivot() v Bojovnik.vb. Připomeňme si, jak vypadá:

Public Function GrafickyZivot() As String
        Dim s As String = "["
        Dim celkem As Integer = 20
        Dim pocet As Double = Math.Round((zivot / maxZivot) * celkem)
        If (pocet = 0) AndAlso (Nazivu()) Then
                pocet = 1
        End If
        For i As Integer = 0 To pocet - 1
                s += "#"
        Next
        s = s.PadRight(celkem + 1)
        s += "]"
        Return s
End Function

Vidíme, že není kromě proměnných zivot a maxZivot na životě nijak závislá. Metodu přejmenujeme na GrafickyUkazatel a dáme ji 2 parametry: aktuální hodnotu a maximální hodnotu. zivot a maxZivot v těle metody poté nahradíme za aktualni a maximalni. Modifikátor bude Protected, abychom metodu mohli v potomkovi použít:

Protected Function GrafickyUkazatel(aktualni As Integer, maximalni As Integer) As String
        Dim s As String = "["
        Dim celkem As Integer = 20
        Dim pocet As Double = Math.Round((aktualni / maximalni) * celkem)
        If (pocet = 0) AndAlso (Nazivu()) Then
                pocet = 1
        End If
        For i As Integer = 0 To pocet - 1
                s += "#"
        Next
        s = s.PadRight(celkem + 1)
        s += "]"
        Return s
End Function

Metodu GrafickyZivot() v Bojovnik.cs naimplementujeme znovu, bude nám v ní stačit jediný řádek a to zavolání metody GrafickyUkazatel() s příslušnými parametry:

Public Function GrafickyZivot() As String
        Return GrafickyUkazatel(zivot, maxZivot)
End Function

Určitě jsem mohl v tutoriálu s bojovníkem udělat metodu GrafickyUkazatel() rovnou. Chtěl jsem však, abychom si ukázali, jak se řeší případy, kdy potřebujeme vykonat podobnou funkčnost vícekrát. S takovouto parametrizací se v praxi budete setkávat často, protože nikdy přesně nevíme, co budeme v budoucnu od našeho programu požadovat.

Nyní můžeme vykreslovat ukazatel tak, jak se nám to hodí. Přesuňme se do Mag.vb a naimplementujme metodu GrafickaMana():

Public Function GrafickaMana() As String
        Return GrafickyUkazatel(mana, maxMana)
End Function

Jednoduché, že? Nyní je mág hotový, zbývá jen naučit arénu zobrazovat manu v případě, že je bojovník mág. Přesuňme se tedy do Arena.vb.

Rozpoznání typu objektu

Jelikož se nám nyní vykreslení bojovníka zkomplikovalo, uděláme si na něj samostatnou metodu VypisBojovnika(), jejím parametrem bude daná instance bojovníka:

Private Sub VypisBojovnika(b As Bojovnik)
        Console.WriteLine(b)
        Console.Write("Zivot: ")
        Console.WriteLine(b.GrafickyZivot())
End Sub

Nyní pojďme reagovat na to, jestli je bojovník mág. Minule jsme si řekli, že k tomu slouží operátor TypeOf a Is:

Private Sub VypisBojovnika(b As Bojovnik)
        Console.WriteLine(b)
        Console.Write("Zivot: ")
        Console.WriteLine(b.GrafickyZivot())
        If TypeOf b Is Mag Then
                Console.Write("Mana:  ")
                Console.WriteLine(DirectCast(b, Mag).GrafickaMana())
        End If
End Sub

Bojovníka jsme museli na mága přetypovat, abychom se k metodě GrafickaMana() dostali. Samotný Bojovnik ji totiž nemá. To bychom měli, VypisBojovnika budeme volat v metodě Vykresli(), která bude vypadat takto:

Private Sub Vykresli()
        Console.Clear()
        Console.WriteLine("-------------- Aréna -------------- " & vbLf)
        Console.WriteLine("Bojovníci: " & vbLf)
        VypisBojovnika(bojovnik1)
        Console.WriteLine()
        VypisBojovnika(bojovnik2)
        Console.WriteLine()
End Sub

Hotovo :)

Tahová hra aréna s mágem v C#

Aplikaci ještě můžeme dodat hezčí vzhled, vložil jsem ASCIIart nadpis Aréna, který jsem vytvořil touto aplikací: http://patorjk.com/software/taag . Navíc jsem obarvil ukazatele pomocí barvy pozadí a popředí. Metodu k vykreslení ukazatele jsem upravil tak, aby vykreslovala plný obdelník místo # (ten napíšete pomocí Alt + 219). Výsledek může vypadat takto:

Tahová hra aréna s mágem v C#

Kód máte v příloze. Pokud jste něčemu nerozuměli, zkuste si článek přečíst vícekrát nebo pomaleji, jsou to důležité praktiky. Příště si vysvětlíme pojem statika.


 

Stáhnout

Staženo 204x (84 kB)
Aplikace je včetně zdrojových kódů v jazyce VB

 

  Aktivity (3)

Článek pro vás napsal Michal Žůrek (misaz)
Avatar
Autor se věnuje tvorbě aplikací pro počítače, mobilní telefony, mikroprocesory a tvorbě webových stránek a webových aplikací. Nejraději programuje ve Visual Basicu a TypeScript. Ovládá HTML, CSS, JavaScript, TypeScript, C# a Visual Basic.

Jak se ti líbí článek?
Celkem (2 hlasů) :
55555


 



 

 

Komentáře

Avatar
Jaroslav Trojan:

Mám vlastní kód na Arenu s Mágem a funguje, jen nemohu přijít na to, proč mi to nepíše :
" utrpěl poškození ...hp ". Tu metodu BranSe() mi to vynechává ,asi,....nevím.

Public Class Bojovnik
Protected jmeno As String
Protected zivot As Integer
Protected maxZivot As Integer
Protected utok As Integer
Protected obrana As Integer
'instance kostky
Protected kostka As Kostka
Public zprava As String
Protected mana As Integer
Protected maxMana As Integer
Protected magickyUtok As Integer

'pro atributy vytvořme konstruktor-instance bojovníka
Public Sub New(jmeno As String, zivot As Integer, utok As Integer, obrana As Integer, kostka As Kostka)
Me.jmeno = jmeno
Me.zivot = zivot
Me.maxZivot = zivot
Me.utok = utok
Me.obrana = obrana
Me.kostka = kostka
End Sub
Public Overrides Function ToString() As String
Return jmeno
End Function
Public Function Nazivu() As Boolean
Return (zivot > 0)
End Function
' Public Sub BranSe1(uder As Integer)
' Dim zraneni As Integer = uder - (obrana + kostka.hod())
' If zraneni > 0 Then
' zivot -= zraneni
' If zivot <= 0 Then zivot = 0
' End If
' End Sub
Protected Function GrafUkazatel(ak­tualni As Integer, maximalni As Integer) As String
Dim s As String = "["
Dim celkem As Integer = 20
Dim pocet As Double = Math.Round Then
pocet = 1
End If
For i As Integer = 0 To pocet - 1
s += "#"
Next
s = s.PadRight(celkem + 1)
s += "]"
Return s
End Function
Public Function GrafZivot() As String
Dim s As String = "["
Dim celkem As Integer = 20
Dim pocet As Double = Math.Round Then
pocet = 1
End If
For i As Integer = 0 To pocet - 1
s += "#"
Next
s = s.PadRight(celkem + 1)
s += "]"
Return s
End Function

Protected Sub NastavZpravu(zprava As String)
Me.zprava = zprava
End Sub
Public Function VratPosledniZ­pravu() As String
Return Me.zprava
End Function

Public Overridable Sub Utoc(souper As Bojovnik)

Dim uder As Integer = utok + kostka.hod()
NastavZpravu([Strin­g].Format("{0} útočí s úderem za {1}hp ", jmeno, uder))
souper.BranSe(uder)

End Sub
Public Sub BranSe(uder As Integer)
Dim zraneni As Integer = uder - (obrana + kostka.hod())
' Console.Write­Line("úder:" & uder & "")
' Console.Write­Line("zranění:" & zraneni & "")
If zraneni > 0 Then
zivot -= zraneni
Dim zprava = [String].Format("{0} utrpěl poškození {1}hp", jmeno, zraneni)
If zivot <= 0 Then
zivot = 0
zprava += " a zemřel"
End If
Else
zprava = [String].Format("{0} odrazil útok", jmeno)
NastavZpravu(zpra­va)
End If
End Sub
End Class

Module Module1
Sub Main()
' Dim kostka As Kostka = New Kostka()
' Console.Write­Line(kostka.Vrat­PocetSten())
' Console.ReadKey()
' Dim kostka As Kostka = New Kostka(14)
' Console.Write­Line(kostka.Vrat­PocetSten())
' Console.ReadKey()
' Dim krychle As Kostka = New Kostka()
' Dim ctrnactisten As Kostka = New Kostka(14)
' Console.Write­Line(krychle.Vrat­PocetSten())
' Console.Write­Line(ctrnactis­ten.VratPocet­Sten())
' Console.ReadKey()

'budeme kostkami v cyklu házet
Dim krychle As Kostka = New Kostka()
Dim ctrnactisten As Kostka = New Kostka(14)
'hod krychlí
Console.Write­Line("Kostka s {0} stěnami", krychle.VratPo­cetSten)
For i = 0 To 9
Console.Write(krychle­.hod() & " ")
Next
Console.WriteLine() : Console.WriteLine()
'hod 14ti stěnem
Console.Write­Line("Kostka s {0} stěnami", ctrnactisten.Vrat­PocetSten)
For i = 0 To 9
Console.Write(ctrnac­tisten.hod() & " ")
Next

Console.ReadKey()
' Dim krychle As Kostka = New Kostka(6)
Dim souper As Bojovnik = New Bojovnik("Boran", 50, 10, 10, krychle)
Dim bojovnik As Bojovnik = New Bojovnik("Zagoran", 100, 50, 10, krychle)
Console.Write­Line("Bojovník:{0}", bojovnik) 'test ToString...jmeno
Console.Write­Line("Naživu:{0}", bojovnik.Nazivu()) 'test Nazivu
Console.Write­Line("Život:{0}", bojovnik.Graf­Zivot()) 'test života
bojovnik.Utoc(bo­jovnik) 'test útoku
Console.Write­Line("život po útoku:{0}", bojovnik.Graf­Zivot())
souper.Utoc(bo­jovnik)
Console.Write­Line("život:{0}", souper.GrafZivot())
Console.Write­Line(souper.Vrat­PosledniZpravu())
Console.Write­Line(bojovnik­.VratPosledniZ­pravu())
Console.Write­Line("život Zagorana po útoku:{0}", bojovnik.Graf­Zivot())
Console.Write­Line("Bojovnik: {0}", souper)
bojovnik.Utoc(sou­per)
Console.Write­Line("život Borana po útoku:{0}", souper.GrafZivot())
Console.Write­Line("Konec prvního zápasu Zagoran-Boran")

Console.ReadKey()

'vytvoření objektů
Console.Write­Line("následu­je zápas Zagoran-Mág Gandalf")
Dim zagoran As New Bojovnik("Zagoran", 100, 25, 10, krychle)
Dim gandalf As New Mag("Gandalf", 50, 15, 12, krychle, 30, 45)
Dim arena As New Arena(zagoran, gandalf, krychle)

'zápas
arena.Zapas()
Console.ReadKey()
End Sub
End Module

Imports System.Threading
Public Class Arena
Public bojovnik1 As Bojovnik
Public bojovnik2 As Bojovnik
Public kostka As Kostka
Public Sub New(bojovnik1 As Bojovnik, bojovnik2 As Bojovnik, kostka As Kostka)
Me.bojovnik1 = bojovnik1
Me.bojovnik2 = bojovnik2
Me.kostka = kostka
End Sub
Private Sub Vykresli()
Console.Clear()
Console.WriteLine("-----------------ARENA------------------" & vbLf)
Console.Write­Line("Bojovní­ci::" & vbLf)
VypisBojovnika(bo­jovnik1)
Console.WriteLine()
VypisBojovnika(bo­jovnik2)
Console.WriteLine()
End Sub
Public Sub VypisZpravu(zprava As String)
Console.Write­Line(zprava)
Thread.Sleep(700)
End Sub
Public Sub Zapas()
Dim b1 As Bojovnik = bojovnik1
Dim b2 As Bojovnik = bojovnik2
Console.Write­Line("Vítejte v Aréně!")
Console.Write­Line("Dnes se utkají {0} s {1}!" & vbLf, bojovnik1, bojovnik2)
Console.Write­Line("Zápas může začít....")
'prohození bojovníků
Dim zacinaBojovnik2 As Boolean = (kostka.hod() <= kostka.VratPo­cetSten() / 2)
If zacinaBojovnik2 Then
b1 = bojovnik2
b2 = bojovnik1
End If
Console.Write­Line("Začínat bude bojovnik {0}!" & vbLf & "Zápas může začít...", b1)
Console.ReadKey()
'cyklus s bojem
While b1.Nazivu() AndAlso b2.Nazivu()
b1.Utoc(b2)
Vykresli()
VypisZpravu(b1­.VratPosledniZ­pravu())
'zpráva o útoku
VypisZpravu(b2­.VratPosledniZ­pravu())
'zpráva o obraně
If b2.Nazivu() Then
Console.Write­Line("b2.žije", b2)
b2.Utoc(b1)
Vykresli()
VypisZpravu(b2­.VratPosledniZ­pravu())
'zpráva o útoku
'zpráva o obraně
VypisZpravu(b1­.VratPosledniZ­pravu())
End If
Console.WriteLine(" ")

End While
If b1.Nazivu() Then Console.Write(b1) : Console.Write(" žije")

If b2.Nazivu() Then Console.Write(b2) : Console.Write(" žije")
Console.WriteLine(" Zápas skončil")
End Sub
Private Sub VypisBojovnika(b As Bojovnik)
Console.Write­Line(b)
Console.Write("Ži­vot:")
Console.Foregrou­ndColor = ConsoleColor.Red
Console.Backgrou­ndColor = ConsoleColor.Dar­kRed
Console.Write­Line(b.GrafZi­vot())
Console.Reset­Color()
If TypeOf b Is Mag Then
Console.Write("Ma­na: ")
Console.Foregrou­ndColor = ConsoleColor.Blue
Console.Backgrou­ndColor = ConsoleColor.Dar­kBlue
Console.Write­Line(DirectCas­t(b, Mag).GrafMana())
Console.Reset­Color()
End If
End Sub

End Class

poradi mi někdo? Díky

 
Odpovědět 5. července 9:11
Avatar
Adam Ježek
Tým ITnetwork
Avatar
Odpovídá na Jaroslav Trojan
Adam Ježek:

Posíláš kódy jako plaintext, a už poněkolikáté.
Jsi tu aktivní již skoro čtvrt roku, pamatuji si, že už minimálně jednou jsem ti říkal, jak vkládat kód a jak vkládat dlouhý kód, a nebyl jsem jediný, kdo ti to říkal.

Další komemtář, který nebude splňovat určitá pravidla pro vložení kódu ti bez jakéhokoliv oznámení smažu hned, jak si ho všimnu.

Odpovědět 5. července 12:36
Programátor dělá co může. Počítač co chce. | Pokud mi dáš mínus, tak prosim, napiš proč!
Avatar
Jaroslav Trojan:

Už jsem na to přišel, program funguje správně! Není třeba mi odpovídat.

 
Odpovědět 8. července 13:16
Děláme co je v našich silách, aby byly zdejší diskuze co nejkvalitnější. Proto do nich také mohou přispívat pouze registrovaní členové. Pro zapojení do diskuze se přihlas. Pokud ještě nemáš účet, zaregistruj se, je to zdarma.

Zobrazeno 3 zpráv z 3.