Diskuze: Zápis souborového systému na disk
V předchozím kvízu, Online test znalostí Assembler, jsme si ověřili nabyté zkušenosti z kurzu.
Neregistrovaný
Neregistrovaný
Domiy:15.6.2013 18:23
Vyčištěno:
BITS 16
jmp short Boot
nop
OEMLabel db "SMA-BOOT" ; Disk label
BytesPerSector dw 512 ; Bytes per sector
SectorsPerCluster db 1 ; Sectors per Cluster
ReservedForBoot dw 1 ; Reserved sectors for boot record
LogicalSectors dw 2880 ; Number of logical sectors
MediumByte db 0F0h ; Medium descriptor byte
SectorsPerTrack dw 18 ; Sectors per track (36/cylinder)
Sides dw 2 ; Number of sides/heads
HiddenSectors dd 0 ; Number of hidden sectors
LargeSectors dd 0 ; Number of LBA sectors
DriveNo dw 0 ; Drive No: 0
Signature db 41 ; Drive signature: 41 for disk
VolumeID dd 00000000h
VolumeLabel db "SMA-OP "
FileSystem db "DSP "
SMA.Load:
mov ah, 42h
mov al, 37
mov cl, 2
mov si, 32768
mov bx, si
int 13h
ret
Boot:
mov ax, 07C0h ; Set up 4K of stack space above Buffer
add ax, 544 ; 8k Buffer = 512 paragraphs + 32 paragraphs (loader)
cli ; Disable interrupts while changing stack
mov ss, ax
mov sp, 4096
sti ; Restore interrupts
mov ax, 07C0h ; Set data segment to where we're loaded
mov ds, ax
; NOTE: A few early BIOSes are reported to improperly set DL
cmp dl, 0
je NoChange
mov [bootDev], dl ; Save boot device number
mov ah, 8h ; Get drive parameters
int 13h
jc FataldiskError
NoChange:
mov eax, 0
mov cx, 32768
call SMA.Load
jc FataldiskError
mov ax, 0
mov bx, 0
mov cx, 0
mov dx, 0
mov di, 0
mov si, 0
jmp 32768
PrintString:
pusha
mov ah, 0Eh
.write:
lodsb
cmp al, 0
je .done
int 10h
jmp short .write
.done:
popa
ret
FataldiskError:
mov si, diskError
call PrintString
Reboot:
mov ax, 0
int 16h ; Wait for keystroke
mov ax, 0
int 19h
diskError db "Disk error! Press any key...", 0
bootDev db 0 ; Boot device number
times 510-($-$$) db 0 ; Pad remainder of boot sector with zeros
dw 0AA55h ; Boot signature (DO NOT CHANGE!)
Buffer: ; Disk Buffer begins (8k after this, stack starts)Jediné čím si nejsem jist - zda se správně nastaví buffer. To se
dozvím později... 
Neregistrovaný
Domiy:17.6.2013 15:28
Už mi pomohl ten kamarád, co mi opravil disk. Sector a Secntor je jako AX a AL.
.SMA.Load.Params:
dw 10h ; structure length
dw 38 ; sector count
dw 7c00h ; buffer address (offset)
dw 0 ; buffer address (segment)
dd 1 ; Secntor number (low 32 bits)
dd 0 ; Sector number (high 32 bits)Nejde. Kernel je hned za VBR a má 38 sektorů. (disk s VBR 39) Chci načíst
ten kernel. Tak jak? (zoufale)
Díky.
Neregistrovaný
Domiy:18.6.2013 7:16
Vzal jsem vše potřebné z VFAT a stejně k ničemu...
BITS 16
jmp short Boot
nop
db "SMA-BOOT" ; Disk label
dw 512 ; Bytes per sector
db 1 ; Sectors per Cluster
dw 1 ; Reserved sectors for boot record
db 2 ; Number of copies of the DSP
dw 0 ; Number of root directory entires
dw 39 ; Number of logical sectors
db 0F0h ; Medium descriptor byte
dw 0 ; Sectors per FAT
dw 63 ; Sectors per track
dw 2 ; Number of sides/heads
dd 0 ; Number of hidden sectors
dd 0 ; Number of LBA sectors
dw 0 ; Drive No: 0
db 41 ; Drive signature: 41 for disk
dd 00000000h ; Volume ID
db "SMA-OP " ; Volume label
db "DSP " ; File System
Boot:
mov ax, 07C0h ; Set up 4K of stack space above Buffer
add ax, 544 ; 8k Buffer = 512 paragraphs + 32 paragraphs (loader)
cli ; Disable interrupts while changing stack
mov ss, ax
mov sp, 4096
sti ; Restore interrupts
cmp dl, 0 ; A few early BIOSes are reported to improperly set DL
je NoChange
mov ah, 8h ; Get drive parameters
int 13h
jc FataldiskError
NoChange:
mov eax, 0 ; Prepare to enter loop
call SMA.Load
jc FataldiskError
jmp 2000h:0000h
PrintString:
pusha
mov ah, 0Eh
.write:
lodsb
cmp al, 0
je .done
int 10h
jmp short .write
.done:
popa
ret
SMA.Load:
mov ah, 42h
mov si, .SMA.Load.Params
int 13h
ret
.SMA.Load.Params:
dw 10h ; structure length
dw 38 ; sector count
dw Buffer ; buffer address (offset)
dw 2000h ; buffer address (segment)
dd 1 ; Secntor number (low 32 bits)
dd 0 ; Sector number (high 32 bits)
FataldiskError:
mov si, diskError
call PrintString
Reboot:
mov ax, 0
int 16h ; Wait for keystroke
mov ax, 0
int 19h
diskError db "Disk error! Press any key...", 0
times 510-($-$$) db 0 ; Pad remainder of boot sector with zeros
dw 0AA55h ; Boot signature (DO NOT CHANGE!)
Buffer: ; Disk Buffer begins (8k after this, stack starts)BITS 16
jmp short Boot
nop
OEMLabel db "SMA-BOOT" ; Disk label
BytesPerSector dw 512 ; Bytes per sector
SectorsPerCluster db 1 ; Sectors per Cluster
ReservedForBoot dw 1 ; Reserved sectors for boot record
NumberOfFATs db 2 ; Number of copies of the FAT
RootDirEntries dw 224 ; Number of entries in root dir
; (224 * 32 = 7168 = 14 sectors to read)
LogicalSectors dw 2880 ; Number of logical sectors
MediumByte db 0F0h ; Medium descriptor byte
SectorsPerFAT dw 9 ; Sectors per FAT
SectorsPerTrack dw 18 ; Sectors per track (36/cylinder)
Sides dw 2 ; Number of sides/heads
HiddenSectors dd 0 ; Number of hidden sectors
LargeSectors dd 0 ; Number of LBA sectors
DriveNo dw 0 ; Drive No: 0
Signature db 41 ; Drive signature: 41 for disk
VolumeID dd 00000000h ; Volume ID: any number
VolumeLabel db "SMA-OP " ; Volume Label: any 11 chars
FileSystem db "FAT12 " ; File system type: don't change!
Boot:
mov ax, 07C0h ; Set up 4K of stack space above Buffer
add ax, 544 ; 8k Buffer = 512 paragraphs + 32 paragraphs (loader)
cli ; Disable interrupts while changing stack
mov ss, ax
mov sp, 4096
sti ; Restore interrupts
mov ax, 07C0h ; Set data segment to where we're loaded
mov ds, ax
; NOTE: A few early BIOSes are reported to improperly set DL
cmp dl, 0
je NoChange
mov [BootDev], dl ; Save boot device number
mov ah, 8 ; Get drive parameters
int 13h
jc FatalDiskError
and cx, 3Fh ; Maximum sector number
mov [SectorsPerTrack], cx ; Sector numbers start at 1
movzx dx, dh ; Maximum head number
add dx, 1 ; Head numbers start at 0 - add 1 for total
mov [Sides], dx
NoChange:
mov eax, 0 ; Needed for some older BIOSes
; First, we need to load the root directory from the disk. Technical details:
; Start of root = ReservedForBoot + NumberOfFATs * SectorsPerFAT = logical 19
; Number of root = RootDirEntries * 32 bytes/entry / 512 bytes/sector = 14
; Start of user data = (start of root) + (number of root) = logical 33
DiskOK: ; Ready to read first block of data
mov ax, 19 ; Root dir starts at logical sector 19
call l2hts
mov si, Buffer ; Set ES:BX to point to our Buffer (see End of code)
mov bx, ds
mov es, bx
mov bx, si
mov ah, 2 ; Params for int 13h: read disk sectors
mov al, 14 ; And read 14 of them
pusha ; Prepare to enter loop
ReadRootDir:
popa ; In case registers are altered by int 13h
pusha
stc ; A few BIOSes do not set properly on error
int 13h ; Read sectors using BIOS
jnc SearchDir ; If read went OK, skip ahead
call ResetDisk ; Otherwise, reset disk controller and try again
jnc ReadRootDir ; Floppy reset OK?
jmp Reboot ; If not, Fatal double error
SearchDir:
popa
mov ax, ds ; Root dir is now in [Buffer]
mov es, ax ; Set DI to this info
mov di, Buffer
mov cx, word [RootDirEntries] ; Search all (224) entries
mov ax, 0 ; Searching at offset 0
NextRootEntry:
xchg cx, dx ; We use CX in the inner loop...
mov si, KernelFname ; Start searching for kernel filename
mov cx, 11
rep cmpsb
je FoundFileToLoad ; Pointer DI will be at offset 11
add ax, 32 ; Bump searched entries by 1 (32 bytes per entry)
mov di, Buffer ; Point to next entry
add di, ax
xchg dx, cx ; Get the original CX back
loop NextRootEntry
mov si, KernelMiss ; If kernel is not found, bail out
call PrintString
jmp Reboot
FoundFileToLoad: ; Fetch Cluster and load FAT into RAM
mov ax, word [es:di+0Fh] ; Offset 11 + 15 = 26, contains 1st Cluster
mov word [Cluster], ax
mov ax, 1 ; Sector 1 = first sector of first FAT
call l2hts
mov di, Buffer ; ES:BX points to our Buffer
mov bx, di
mov ah, 2 ; int 13h params: read (FAT) sectors
mov al, 9 ; All 9 sectors of 1st FAT
pusha ; Prepare to enter loop
ReadFAT:
popa ; In case registers are altered by int 13h
pusha
stc
int 13h ; Read sectors using the BIOS
jnc ReadFAT_OK ; If read went OK, skip ahead
call ResetDisk ; Otherwise, reset disk controller and try again
jnc ReadFAT ; Floppy reset OK?
FatalDiskError:
mov si, DiskError ; If not, print error message and Reboot
call PrintString
jmp Reboot ; Fatal double error
ReadFAT_OK:
popa
mov ax, 2000h ; Segment where we'll load the kernel
mov es, ax
mov bx, 0
mov ah, 2 ; int 13h disk read params
mov al, 1
push ax ; Save in case we (or int calls) lose it
; Now we must load the FAT from the disk. Here's how we find out where it starts:
; FAT Cluster 0 = media descriptor = 0F0h
; FAT Cluster 1 = filler Cluster = 0FFh
; Cluster start = ((Cluster number) - 2) * SectorsPerCluster + (start of user)
; = (Cluster number) + 31
LoadFileSector:
mov ax, word [Cluster] ; Convert sector to logical
add ax, 31
call l2hts ; Make appropriate params for int 13h
mov ax, 2000h
mov es, ax
mov bx, word [Pointer]
pop ax
push ax
stc
int 13h
jnc CalculateNextCluster
call ResetDisk
jmp LoadFileSector
CalculateNextCluster:
mov ax, [Cluster]
mov dx, 0
mov bx, 3
mul bx
mov bx, 2
div bx ; DX = [Cluster] mod 2
mov si, Buffer
add si, ax ; AX = word in FAT for the 12 bit entry
mov ax, word [ds:si]
or dx, dx ; If DX = 0 [Cluster] is Even; if DX = 1 then it's Odd
jz Even ; If [Cluster] is Even, drop last 4 bits of word
; with next Cluster; if Odd, drop first 4 bits
Odd:
shr ax, 4 ; Shift out first 4 bits (they belong to another entry)
jmp short NextClusterCont
Even:
and ax, 0FFFh ; Mask out final 4 bits
NextClusterCont:
mov word [Cluster], ax ; Store Cluster
cmp ax, 0FF8h ; FF8h = End of file marker in FAT12
jae End
add word [Pointer], 512 ; Increase Buffer Pointer 1 sector length
jmp LoadFileSector
End: ; We've got the file to load!
pop ax ; Clean up the stack (AX was pushed earlier)
mov dl, byte [BootDev] ; Provide kernel with boot device info
jmp 2000h:0000h ; Jump to entry point of loaded kernel!
Reboot:
mov ax, 0
int 16h ; Wait for keystroke
mov ax, 0
int 19h ; Reboot the system
PrintString:
pusha
mov ah, 0Eh
.write:
lodsb
cmp al, 0
je .done
int 10h
jmp short .write
.done:
popa
ret
ResetDisk:
push ax
push dx
mov ax, 0
mov dl, byte [BootDev]
stc
int 13h
pop dx
pop ax
ret
l2hts: ; Calculate head, track and sector settings for int 13h
; IN: logical sector in AX, OUT: correct registers for int 13h
push bx
push ax
mov bx, ax ; Save logical sector
mov dx, 0 ; First the sector
div word [SectorsPerTrack]
add dl, 01h ; Physical sectors start at 1
mov cl, dl ; Sectors belong in CL for int 13h
mov ax, bx
mov dx, 0 ; Now calculate the head
div word [SectorsPerTrack]
mov dx, 0
div word [Sides]
mov dh, dl ; Head/side
mov ch, al ; Track
pop ax
pop bx
mov dl, byte [BootDev] ; Set correct device
ret
KernelFname db "SMA BIN"
DiskError db "HDD error! Press any key.", 0
KernelMiss db "Kernel file SMA.BIN missing.", 0
BootDev db 0 ; Boot device number
Cluster dw 0 ; Cluster of the file we want to load
Pointer dw 0 ; Pointer into Buffer, for loading kernel
times 510-($-$$) db 0 ; Pad remainder of boot sector with zeros
dw 0AA55h ; Boot signature (DO NOT CHANGE!)
Buffer: ; Disk Buffer begins (8k after this, stack starts)První nejde, druhé ano - kde je rozdíl?
Zobrazeno 26 zpráv z 76.